カテゴリー

作成日/修正日 2015/12/22 2015/12/22
対応Cubitバージョン 15.0.1 → 15.2.0
カテゴリー Export→ I-Deas
GUI NO
TUI Renumber
キーワード メッシュ,出力
Key Word I-Deas,Export,Serial,Number,Renumber

複合メッシュをI-Daesへの出力を可能にする方法について(Export-IDeas- Mixed-Scheme

Trelisで複合メッシュ(TetraHeaWedgePyramid)のメッシュをI-deasExportする場合にはそのままではエラーになってしまいます.(Version 2.0まで)これは各Schemeの要素番号はそれぞれ独立に割り付けられているためにScheme間で重複する番号がある場合に起こります.TUIによってこの番号をScheme間に渡って通し番号にすることが可能です.要素を通し番号に変更することでI-DeasへのExportが可能になります.

Fig 1 要素の通し番号への変換

168

作業内容

1. 複合Schemeを含むメッシュを作成します.

2.要素番号を通し番号に変更するジャーナルを実行します.

3.I-DeasへメッシュをExportします.

(ジャーナル)複合メッシュをI-Daesへの出力を可能にする方法(Export-IDeas- Mixed-Scheme)
reset
brick x 4 y 4 z 4
surface 1 2 3 4 5 6 size 1
mesh surface 1 2 3 4 5 6
volume 1 size 5
Volume 1 scheme tetmesh
mesh volume 1
#
# Renumber #############################################
#List the number of elements in each mesh entity type
list hex
list tet
list pyramid
list wedge
list tri
list face
list node
#Create groups of all mesh entitity types
group “hex_group” add hex all
group “tet_group” add tet all
group “pyramid_group” add pyramid all
group “wedge_group” add wedge all
group “tri_group” add tri all
group “face_group” add face all
group “node_group” add node all
#Create variable for number of entities in each entity group
#{_num_hex = NumInGrp(“hex_group”)}
#{_num_tet = NumInGrp(“tet_group”)}
#{_num_pyr = NumInGrp(“pyramid_group”)}
#{_num_wed = NumInGrp(“wedge_group”)}
#{_num_tri = NumInGrp(“tri_group”)}
#{_num_fac = NumInGrp(“face_group”)}
#{_num_nod = NumInGrp(“node_group”)}
#Renumber each entity type group and increment start_id after each group renumber
#{_start_id = 1}
#{if(_num_hex != 0)}
renumber hex all start_id {_start_id} uniqueids
#{_start_id += _num_hex}
#{endif}
#{if(_num_tet != 0)}
renumber tet all start_id {_start_id} uniqueids
#{_start_id += _num_tet}
#{endif}
#{if(_num_pyr != 0)}
renumber pyramid all start_id {_start_id} uniqueids
#{_start_id += _num_pyr}
#{endif}
#{if(_num_wed != 0)}
renumber wedge all start_id {_start_id} uniqueids
#{_start_id += _num_wed}
#{endif}
#{if(_num_tri != 0)}
renumber tri all start_id {_start_id} uniqueids
#{_start_id += _num_tri}
#{endif}
#{if(_num_fac != 0)}
renumber face all start_id {_start_id} uniqueids
#{_start_id += _num_fac}
#{endif}
#{if(_num_nod != 0)}
renumber node all start_id {_start_id} uniqueids
#{_start_id += _num_nod}
#{endif}
#Clean up
#{delete(‘_start_id’)}
#{delete(‘_num_hex’)}
#{delete(‘_num_tet’)}
#{delete(‘_num_pyr’)}
#{delete(‘_num_wed’)}
#{delete(‘_num_tri’)}
#{delete(‘_num_fac’)}
#{delete(‘_num_nod’)}
#Delete the groups
#List the number of elements in each mesh entity type
list hex
list tet
list pyramid
list wedge
list tri
list face
list node
# End of Renumber #############################################
export ideas “Ideas_mesh.unv” overwrite cubitids